please dont rip this site

SX Microcontroller Radix Math Method

Unpacked BCD to 16 bit binary conversion

;*******************************************************************************
; Input: unpacked BCD in  tenk:thou:hund:tens:ones
;Output: 16 bit binary in hi:lo
;  Size: 35 instructions
;Timing: 3+34+3=40 instruction cycles
;
; Notes:
;1) if input is higher than 65535 output is meaningless
;2) algorithm synopsis:
;
;> dec2bin([1 10 100 1000 1e4], 16)
;ans =
;0000000000000001
;0000000000001010
;0000000001100100
;0000001111101000
;0010011100010000
;
;Or coded in three levels ('+' represents +1, '-' represents -1):
;000000000000000+ * ones +
;000000000000+0+0 * tens +
;000000000++00+00 * hund +
;00000+0000-0+000 * thou +
;00+0+00-000+0000 * tenk
;
;bin = (((tens+thou+tenk*256)*2+
;	hund+hund*16+thou*256)*2+
;	tens+hund*16-thou*16+tenk*16*256)*2+
;	ones+tenk*16-tenk*256
;
;January 22, 2001 by Nikolai Golovchenko
;*******************************************************************************

dec2bin16
	mov	W, tens
	add	W, thou
	mov	lo, W
        add     lo, W
	mov	W, <<tenk
	mov	hi, W

	mov	W, <>hund
	add	W, hund
	add	lo, W
	mov	W, thou
	add	hi, W
	rl	lo
	rl	hi

	mov	W, <>hund
	add	W, tens
	add	lo, W
	mov	W, <>tenk
	snc
	or	W, #$01
	add	hi, W
	mov	W, <>thou
	sub	lo, W
	sc
	dec	hi
	clc
	rl	lo
	rl	hi

	mov	W, <>tenk
	add	W, ones
	add	lo, W
	mov	W, tenk
	snc
	mov	W, --tenk
	sub	hi, W
	retp
;*******************************************************************************

See also:


file: /Techref/scenix/lib/math/radix/dec2bin16.htm, 1KB, , updated: 2004/6/10 14:40, local time: 2019/7/16 03:12, owner: NG--944,
TOP NEW HELP FIND: 
34.229.113.106:LOG IN

 ©2019 These pages are served without commercial sponsorship. (No popup ads, etc...).Bandwidth abuse increases hosting cost forcing sponsorship or shutdown. This server aggressively defends against automated copying for any reason including offline viewing, duplication, etc... Please respect this requirement and DO NOT RIP THIS SITE. Questions?
Please DO link to this page! Digg it! / MAKE! / 

<A HREF="http://www.sxlist.com/techref/scenix/lib/math/radix/dec2bin16.htm"> Unpacked BCD to 16 bit binary conversion</A>

After you find an appropriate page, you are invited to your to this massmind site! (posts will be visible only to you before review) Just type in the box and press the Post button. (HTML welcomed, but not the <A tag: Instead, use the link box to link to another page. A tutorial is available Members can login to post directly, become page editors, and be credited for their posts.


Link? Put it here: 
if you want a response, please enter your email address: 
Attn spammers: All posts are reviewed before being made visible to anyone other than the poster.
Did you find what you needed?

 

Welcome to sxlist.com!


Site supported by
sales, advertizing,
& kind contributors
just like you!

Please don't rip/copy
(here's why

Copies of the site on CD
are available at minimal cost.
 

Welcome to www.sxlist.com!

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

  .